# Contributor: Patrick Jackson <PatrickSJackson gmail com>
# Maintainer: Christoph Vigano <mail@cvigano.de>

pkgname=st
pkgver=0.7
pkgrel=1
pkgdesc='A simple virtual terminal emulator for X.'
arch=('i686' 'x86_64')
license=('MIT')
depends=('libxft' 'libxext' 'xorg-fonts-misc' 'dmenu' 'xurls')
makedepends=('ncurses')
url="http://st.suckless.org"
source=(http://dl.suckless.org/st/$pkgname-$pkgver.tar.gz
        config.h
	http://st.suckless.org/patches/st-externalpipe-20160727-308bfbf.diff
	http://st.suckless.org/patches/st-hidecursor-20160727-308bfbf.diff)
md5sums=('29b2a599cf1511c8062ed8f025c84c63'
         '660d6802bd0dcce12d474bf911ffb6db'
         '47d628501defd776efd0d4fbb1968895'
         '8ff8a77b34dfc09a4dd0d2cf876d68e7')

prepare() {
  cd $srcdir/$pkgname-$pkgver
  # skip terminfo which conflicts with nsurses
  sed -i '/\@tic /d' Makefile
  cp $srcdir/config.h config.h
  patch -Np1 -i $srcdir/st-externalpipe-20160727-308bfbf.diff
  patch -Np1 -i $srcdir/st-hidecursor-20160727-308bfbf.diff
}

build() {
  cd $srcdir/$pkgname-$pkgver
  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make PREFIX=/usr DESTDIR="$pkgdir" TERMINFO="$pkgdir/usr/share/terminfo" install
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
}