# Maintainer: David Thurstenson <thurstylark@gmail.com>

pkgname=st-tl
_pkgname=st
pkgver=0.7.r17.gc63a87c
pkgrel=2
pkgdesc='A simple virtual terminal emulator for X.'
arch=('i686' 'x86_64')
license=('MIT')
depends=('libxft' 'libxext' 'xorg-fonts-misc' 'dmenu' 'xurls')
makedepends=('ncurses')
conflicts=('st')
url="http://st.suckless.org"
source=(git://git.suckless.org/st
        tl-config.diff
	st-externalpipe.diff::http://st.suckless.org/patches/st-externalpipe-20161125-e448324.diff
	st-hidecursor.diff::http://st.suckless.org/patches/st-hidecursor-20160727-308bfbf.diff)
md5sums=('SKIP'
         'e19ad498fa62e62de6fe6013d0bff62c'
         'c54c87489342b8d77c6dd8f3c2ff997e'
         '8ff8a77b34dfc09a4dd0d2cf876d68e7')

pkgver() {
	cd "$_pkgname"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd $srcdir/$_pkgname
  # skip terminfo which conflicts with nsurses
  sed -i '/\@tic /d' Makefile
  cp config.def.h config.h
  patch -Np1 -i $srcdir/tl-config.diff
  patch -Np1 -i $srcdir/st-externalpipe.diff
  patch -Np1 -i $srcdir/st-hidecursor.diff
}

build() {
  cd $srcdir/$_pkgname
  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}

package() {
  cd $srcdir/$_pkgname
  make PREFIX=/usr DESTDIR="$pkgdir" TERMINFO="$pkgdir/usr/share/terminfo" install
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
}