#!/usr/bin/gnuplot -c

w = ARG1
h = ARG2

set term png size w,h nocrop

#set term qt persist
set bmargin 0
set lmargin 0
set rmargin 0
set tmargin 0

unset border
unset tics
unset key

set parametric


set xrange [0:w]
set yrange [0:h]

a = 50

set object rectangle from screen 0,0 to screen 1,1 behind fillcolor rgb 'black' fillstyle solid noborder

set style arrow 1 nohead lt rgb "white"

# X Axis
set arrow from w/2,0 to w/2,h arrowstyle 1
# Y Axis
set arrow from 0,h/2 to w,h/2 arrowstyle 1

# Left box side
set arrow from 0,0 to 0,h arrowstyle 1
# Right box side
set arrow from w-1,0 to w-1,h arrowstyle 1
# Top box side
set arrow from 0,h to w,h arrowstyle 1
# Bottom box side
set arrow from 0,0 to w,0 arrowstyle 1

# Diagonal bottom left to top right
set arrow from 0,0 to w,h arrowstyle 1
# Diagonal top left to bottom right
set arrow from 0,h to w,0 arrowstyle 1

# Horizontal 25% line top
set arrow from 0,0.75*h to w,0.75*h arrowstyle 1
# Horizontal 25% line bottom
set arrow from 0,0.25*h to w,0.25*h arrowstyle 1
# Vertical 25% line left
set arrow from 0.25*w,0 to 0.25*w,h arrowstyle 1
# Vertical 25% line right
set arrow from 0.75*w,0 to 0.75*w,h arrowstyle 1

# Circle around midpoint
set obj 10 circle at 0.5*w,0.5*h size 0.20*h fc rgb "white"
# Square around midpoint
set obj 20 rectangle at 0.5*w,0.5*h size 0.40*h,0.40*h fs empty border lc rgb "white" front

plot 0,0
