# Maintainer: David Thurstenson <thurstylark@gmail.com>
pkgbase=tl-archconfig
pkgname=("tl-dmesg-unrestrict" "tl-pacdiff-hook" "tl-reflector-hook" "tl-steamdummy")
pkgver=1
pkgrel=1
pkgdesc="Thurstylark's system-level tweaks for Arch Linux"
arch=(any)
url="https://git.thurstylark.com/tl-archconfig.git"
license=('GPL')
groups=(tlconfig)
source=("tl-dmesg-unrestrict.conf"
	"tl-pacdiff.hook"
	"tl-reflector.hook"
	"tl-reflector.service.override.conf"
	"tl-reflector.conf"
)
sha256sums=('0ccede1887575ae52e57824dd53cd9f65cf13b249a3757097e9c06dc16ac535e'
            'fa4010aefe4ed06d623d5915ed70442c263c41a5eb72014b1084210d4db33ed5'
            '167201c316f9cfabd84fb375c7ee21dcf9c211895b6693053def8c87e27508e1'
            '7801aaf6d28d0bf5f7b8c0e35e04af7201f3178b3b4af07a48a36ab4d1e8d7f1'
            'ffe8c4f0928ffd70d05b3ca04d87f8181aa21214cc62fb4dd71a3753c2a788d0')

package_tl-dmesg-unrestrict() {
	pkgdesc="Set kernel.dmesg)unrestrict=0"

	install -Dm644 tl-dmesg-unrestrict.conf \
		${pkgdir}/usr/lib/sysctl.d/99-tl-dmesg-unrestrict.conf
}

package_tl-pacdiff-hook() {
	pkgdesc="A hook to run pacdiff after any run of pacman"
	depends=('pacman-contrib' 'vim')

	install -Dm644 tl-pacdiff.hook ${pkgdir}/usr/share/libalpm/hooks/pacdiff.hook
}

package_tl-reflector-hook() {
	pkgdesc="A hook to run reflector after an upgrade to pacman-mirrorlist, plus reflector config"
	depends=('reflector')

	install -Dm644 tl-reflector.hook \
			${pkgdir}/usr/share/libalpm/hooks/tl-reflector.hook

	install -Dm644 tl-reflector.service.override.conf \
			${pkgdir}/etc/systemd/system/reflector.service.d/override.conf

	install -Dm644 tl-reflector.conf \
			${pkgdir}/etc/xdg/reflector/tl-reflector.conf
}

package_tl-steamdummy() {
	pkgdesc="Dummy package to satisfy a req for steam"
	provides=(steam)
}