st/PKGBUILD

# Maintainer: David Thurstenson <thurstylark@gmail.com>

pkgname=st-tl
_pkgname=st
pkgver=0.7.r26.gb331da5
pkgrel=1
pkgdesc='A simple virtual terminal emulator for X.'
arch=('i686' 'x86_64')
license=('MIT')
depends=('libxft' 'libxext' 'xorg-fonts-misc' 'dmenu' 'xurls')
makedepends=('ncurses')
conflicts=('st')
url="http://st.suckless.org"
source=('git://git.suckless.org/st#commit=b331da550b290d54592b7ba11242c92f5a303a48'
        tl-config.diff
	st-externalpipe.diff
	st-hidecursor.diff)
md5sums=('SKIP'
         '4d1089c3845767e52f1bd79f0022acb0'
         'a75266ee959386a4b50e0ad7d1c41580'
         '487dc42b84ea464474aac527c2b47191')

pkgver() {
	cd "$_pkgname"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd $srcdir/$_pkgname
  # skip terminfo which conflicts with nsurses
  sed -i '/\@tic /d' Makefile
  cp config.def.h config.h
  patch -Np1 -i $srcdir/tl-config.diff
  patch -Np1 -i $srcdir/st-externalpipe.diff
  patch -Np1 -i $srcdir/st-hidecursor.diff
}

build() {
  cd $srcdir/$_pkgname
  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}

package() {
  cd $srcdir/$_pkgname
  make PREFIX=/usr DESTDIR="$pkgdir" TERMINFO="$pkgdir/usr/share/terminfo" install
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
}