tl-archconfig/PKGBUILD

# Maintainer: David Thurstenson <thurstylark@gmail.com>
pkgbase=tl-archconfig
pkgname=("tl-dmesg-unrestrict" "tl-pacdiff-hook" "tl-reflector-config" "tl-steamdummy")
pkgver=3
pkgrel=1
pkgdesc="Thurstylark's system-level tweaks for Arch Linux"
arch=(any)
url="https://git.thurstylark.com/tl-archconfig.git"
license=('GPL')
groups=(tlconfig)
source=("tl-dmesg-unrestrict.conf"
	"tl-pacdiff.hook"
	"tl-reflector.service.override.conf"
	"tl-reflector.conf"
)
sha256sums=('0ccede1887575ae52e57824dd53cd9f65cf13b249a3757097e9c06dc16ac535e'
            'ffcc1090642178dae38c51618a2c8d9ba75ae3f9ae2994287b5ba44d6f33574a'
            '7801aaf6d28d0bf5f7b8c0e35e04af7201f3178b3b4af07a48a36ab4d1e8d7f1'
            'ffe8c4f0928ffd70d05b3ca04d87f8181aa21214cc62fb4dd71a3753c2a788d0')

package_tl-dmesg-unrestrict() {
	pkgdesc="Set kernel.dmesg)unrestrict=0"

	install -Dm644 tl-dmesg-unrestrict.conf \
		${pkgdir}/usr/lib/sysctl.d/99-tl-dmesg-unrestrict.conf
}

package_tl-pacdiff-hook() {
	pkgdesc="A hook to run pacdiff after any run of pacman"
	depends=('pacman-contrib')

	install -Dm644 tl-pacdiff.hook ${pkgdir}/usr/share/libalpm/hooks/zz-tl-pacdiff.hook
}

package_tl-reflector-config() {
	pkgdesc="Thurstylark's config for reflector"
	depends=('reflector')
	install="tl-reflector-config.install"
	conflicts=('tl-reflector-hook')
	replaces=('tl-reflector-hook')

	install -Dm644 tl-reflector.service.override.conf \
			${pkgdir}/etc/systemd/system/reflector.service.d/override.conf

	install -Dm644 tl-reflector.conf \
			${pkgdir}/etc/xdg/reflector/tl-reflector.conf
}

package_tl-steamdummy() {
	pkgdesc="Dummy package to satisfy a req for steam"
	provides=(steam)
}